/*
 * Copyright (c) 2008, HippoHX Contributors
 * All rights reserved.
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions are met:
 *
 *   - Redistributions of source code must retain the above copyright
 *     notice, this list of conditions and the following disclaimer.
 *   - Redistributions in binary form must reproduce the above copyright
 *     notice, this list of conditions and the following disclaimer in the
 *     documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY THE HIPPOHX PROJECT CONTRIBUTORS "AS IS" AND ANY
 * EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL THE HIPPOHX PROJECT CONTRIBUTORS BE LIABLE FOR
 * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
 * CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH
 * DAMAGE.
 */


package com.hippohx.gui{
	
	import com.hippohx.System;
	import com.hippohx.File;
	import com.hippohx.gui.Utils;
	
	public class HippoHXSettings{
		
		private var lastActivePath:String = "";
		private var latestProjects:/*String*/Array;
		private var system:com.hippohx.System;
		
		public function HippoHXSettings(){
			
			system = com.hippohx.System.getInstance();
			
			lastActivePath = system.getUserFolder();
			latestProjects = new Array();
			
		}
		
		public function save():void{
			
			var filePath:String = Utils.getSettingsFilePath();
			var content:String = getSettingsXML().toXMLString();
			
			File.getInstance().writefile(filePath,content);
			
		}
		
		public function getLastActivePath():String{
			return lastActivePath;
		}
		
		public function removeFromLatestProjects(project:Project):void{
			
			for(var x:uint=0;x<latestProjects.length;x++){
				
				if(latestProjects[x] == project.fullPath){
					
					latestProjects.splice(x,1);
					break;
					
				}
				
			}			
			
		}
		
		public function addToLatestProjects(project:Project):void{
			
			var already:Boolean = false;
			
			for(var x:uint=0;x<latestProjects.length;x++){
				
				if(latestProjects[x] == project.fullPath){
					
					already = true;
					break;
					
				}
				
			}
			
			if(!already){ latestProjects.push(project.fullPath); }
			
		}
		
		public function getLatestProjects():Array{
			return latestProjects;
		}
		
		public function setSettingsXML(settingsXML:XML):void{
			
			lastActivePath = settingsXML.lastActivePath;
			
			latestProjects = new Array();
			
			for(var x:uint;x<settingsXML.latestProjects.project.length();x++){
				
				latestProjects.push(settingsXML.latestProjects.project[x]);
				
			}
			
		}
		
		public function getSettingsXML():XML{
			
			var settingsXML:XML = new XML(
					<data>
						<lastActivePath>{lastActivePath}</lastActivePath>
						<latestProjects></latestProjects>
					</data>
				);
			
			for(var x:uint=0;x<latestProjects.length;x++){
				
				var path:String = latestProjects[x];
				settingsXML.latestProjects.appendChild(<project>{path}</project>);
				
			}
			
			return settingsXML;
			
		}
		
	}
	
}